Write down a formal grammar for Maud

[lambda-fairy]

This would be nice as an appendix of the book.

[lambda-fairy]

Here's an initial attempt using EBNF:

markups = { markup } ;
markup = literal | special form | element | splice | block ;

special form = '@',
    ( 'if', moelarry, block
    | 'if', 'let', pattern, '=', moelarry, block
    | 'while', moelarry, block
    | 'while', 'let', pattern, '=', moelarry, block
    | 'for', pattern, 'in', moelarry, block
    | 'match', moelarry, match body
    | 'let', pattern, '=', moelarry, block
    ) ;
match body = ... ;  (* this is complicated *)

element = name, { normal attribute | empty attribute }, ( markup | '/' ) ;
name = identifier, { '-', identifier } ;
normal attribute = name, '=', attribute value ;
attribute value = literal | special form | splice | attribute block ;
attribute block = '{', attribute value, '}' ;
empty attribute = name, '?', [ '[', expression, ']' ] ;

splice = '(', expression, ')' ;

block = '{', markups, '}' ;

identifier = ? Rust identifier ? ;
literal = ? Rust string literal ? ;
expression = ? Rust expression ? ;
moelarry = ? Rust expression excluding struct literals ? ;
pattern = ? Rust pattern ? ;

(See rust-lang/rfcs#1384 (comment) for an explanation of the term "moelarry".)

Seems pretty straightforward, except for the @match syntax (I'm not really familiar with that part of the parser).

[lambda-fairy]

I don't think anyone is asking for this.