build.gradle

plugins {
    id 'java'
    alias(libs.plugins.axionRelease)
    alias(libs.plugins.nexusPublish)
}

apply plugin: 'java'

group = 'org.rundeck.plugins'
ext.publishName = "Slack Incoming Webhook Plugin ${project.version}"
ext.publishDescription = project.description ?: 'Rundeck Plugin to send Slack Webhook'
ext.githubSlug = 'rundeck-plugins/slack-incoming-webhook-plugin'
ext.developers = [
        [id: 'gschueler', name: 'Greg Schueler', email: 'greg@rundeck.com']
]

java {
    sourceCompatibility = JavaVersion.VERSION_11
    withJavadocJar()
    withSourcesJar()
}

configurations{
    //declare custom pluginLibs configuration to include only libs for this plugin
    pluginLibs

    //declare compile to extend from pluginLibs so it inherits the dependencies
    implementation {
        extendsFrom pluginLibs
    }
}

scmVersion {
    ignoreUncommittedChanges = true
    tag {
        prefix = 'v'
        versionSeparator = ''
    }
}
project.version = scmVersion.version

repositories {
    mavenCentral()
}

dependencies {
    pluginLibs libs.freemarker
    implementation(libs.rundeckCore) {
        exclude(group: "com.jcraft")
    }
}

// task to copy plugin libs to output/lib dir
tasks.register('copyToLib', Copy) {
    into "$buildDir/output/lib"
    from configurations.pluginLibs
}

jar {
    //include contents of output dir
    from "$buildDir/output"
    manifest {
        attributes 'Rundeck-Plugin-Name' : 'Slack Notification'
        attributes 'Rundeck-Plugin-Description' : 'Sends Rundeck notification messages to a slack channel.'
        attributes 'Rundeck-Plugin-Rundeck-Compatibility-Version': '2.8.2+'
        attributes 'Rundeck-Plugin-Tags': 'java,notification,slack'
        attributes 'Rundeck-Plugin-License': 'Apache 2.0'
        attributes 'Rundeck-Plugin-Source-Link': 'https://github.com/rundeck-plugins/slack-incoming-webhook-plugin'
        attributes 'Rundeck-Plugin-Target-Host-Compatibility': 'all'
        attributes 'Rundeck-Plugin-Author': 'Rundeck, Inc.'
        attributes 'Rundeck-Plugin-Version': '1.2', 'Rundeck-Plugin-Archive': 'true','Rundeck-Plugin-File-Version': "${project.version}"
        //create space-separated list of pluginLibs
        def libList = configurations.pluginLibs.collect{'lib/'+it.name}.join(' ')
        attributes 'Rundeck-Plugin-Classnames': 'com.bitplaces.rundeck.plugins.slack.SlackNotificationPlugin', 'Rundeck-Plugin-Libs': "${libList}"
    }
}

//set jar task to depend on copyToLib
jar.dependsOn(copyToLib)

nexusPublishing {
    packageGroup = 'org.rundeck.plugins'
    repositories {
        sonatype()
    }
}


apply from: "${rootDir}/gradle/publishing.gradle"