[#153] Max function length rule

src/elvis_style.erl

@@ -18,7 +18,8 @@
          state_record_and_type/3,
          no_spec_with_records/3,
          dont_repeat_yourself/3,
-         max_module_length/3
+         max_module_length/3,
+         max_function_length/3
         ]).
 
 -define(LINE_LENGTH_MSG, "Line ~p is too long: ~s.").
@@ -91,6 +92,10 @@
         "The code for module ~p has ~p lines which exceeds the "
         "maximum of ~p.").
 
+-define(MAX_FUNCTION_LENGTH,
+        "The code for function ~p has ~p lines which exceeds the "
+        "maximum of ~p.").
+
 %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
 %% Rules
 %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
@@ -407,6 +412,44 @@ max_module_length(Config, Target, RuleConfig) ->
             []
     end.
 
+-spec max_function_length(elvis_config:config(),
+                          elvis_file:file(),
+                          empty_rule_config()) ->
+    [elvis_result:item()].
+max_function_length(Config, Target, RuleConfig) ->
+    MaxLength = maps:get(max_length, RuleConfig, 30),
+
+    {Root, _} = elvis_file:parse_tree(Config, Target),
+
+    IsFunction = fun(Node) -> ktn_code:type(Node) == function end,
+    Functions = elvis_code:find(IsFunction, Root),
+    PairFun =
+        fun(FunctionNode) ->
+                Name = ktn_code:attr(name, FunctionNode),
+                L = function_line_length(FunctionNode),
+                {Name, L}
+        end,
+    FunLenPairs = lists:map(PairFun, Functions),
+    MaxLengthPred = fun({_, L}) -> L > MaxLength end,
+    FunLenMaxPairs = lists:filter(MaxLengthPred, FunLenPairs),
+
+    ResultFun =
+        fun({Name, L}) ->
+                Info = [Name, L, MaxLength],
+                Msg = ?MAX_FUNCTION_LENGTH,
+                elvis_result:new(item, Msg, Info, 0)
+        end,
+    lists:map(ResultFun, FunLenMaxPairs).
+
+-spec function_line_length(ktn_code:tree_node())-> [{atom(), integer()}].
+function_line_length(FunctionNode) ->
+    Zipper = elvis_code:code_zipper(FunctionNode),
+    LineFun = fun(N) -> {L, _} = ktn_code:attr(location, N), L end,
+    LineNums = zipper:map(LineFun, Zipper),
+    Max = lists:max(LineNums),
+    Min = lists:min(LineNums),
+    (Max - Min) + 1.
+
 %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
 %% Private
 %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%

test/examples/fail_max_function_length.erl

@@ -0,0 +1,36 @@
+-module(fail_max_function_length).
+
+-export([f5/1, f10/1, f15/1]).
+
+f5(_) -> %% 1
+    %% 2
+    %% 3
+    %% 4
+    ok. %% 5
+
+f10(_) -> %% 1
+    %% 2
+    %% 3
+    %% 4
+    %% 5
+    %% 6
+    %% 7
+    %% 8
+    %% 9
+    ok.
+
+f15(_) -> %% 1
+    %% 2
+    %% 3
+    %% 4
+    %% 5
+    %% 6
+    %% 7
+    %% 8
+    %% 9
+    %% 10
+    %% 11
+    %% 12
+    %% 13
+    %% 14
+    ok.

test/style_SUITE.erl

@@ -25,6 +25,7 @@
          verify_no_spec_with_records/1,
          verify_dont_repeat_yourself/1,
          verify_max_module_length/1,
+         verify_max_function_length/1,
          %% Non-rule
          results_are_ordered_by_line/1
         ]).
@@ -351,6 +352,27 @@ verify_max_module_length(_Config) ->
     RuleConfig2 = #{max_length => 15},
     [] = elvis_style:max_module_length(ElvisConfig, FileFail, RuleConfig2).
 
+-spec verify_max_function_length(config()) -> any().
+verify_max_function_length(_Config) ->
+    ElvisConfig = elvis_config:default(),
+    SrcDirs = elvis_config:dirs(ElvisConfig),
+
+    PathFail = "fail_max_function_length.erl",
+    {ok, FileFail} = elvis_test_utils:find_file(SrcDirs, PathFail),
+    RuleConfig = #{max_length => 4},
+    [_, _, _] =
+         elvis_style:max_function_length(ElvisConfig, FileFail, RuleConfig),
+
+    RuleConfig1 = #{max_length => 9},
+    [_, _] =
+        elvis_style:max_function_length(ElvisConfig, FileFail, RuleConfig1),
+
+    RuleConfig2 = #{max_length => 14},
+    [_] = elvis_style:max_function_length(ElvisConfig, FileFail, RuleConfig2),
+
+    RuleConfig3 = #{max_length => 15},
+    [] = elvis_style:max_function_length(ElvisConfig, FileFail, RuleConfig3).
+
 -spec results_are_ordered_by_line(config()) -> any().
 results_are_ordered_by_line(_Config) ->
     ElvisConfig = elvis_config:default(),