Merging images into single PDF

README.md

@@ -24,6 +24,17 @@ Clojure PDF manipulation library & wrapper for [PDFBox](http://pdfbox.apache.org
 (pdf/merge-pdfs :input ["test/pdfs/clojure-1.pdf" "test/pdfs/clojure-2.pdf"] :output "foo.pdf")
 ```
 
+### Merge multiple images into single PDF
+
+You can use either `merge-images-from-path` for providing images in form of vector of string paths or
+`merge-images-from-byte-array` to provide them as a vector of byte arrays. Each image will be inserted into its own
+page.
+
+```clojure
+(require '[pdfboxing.merge :as pdf])
+(pdf/merge-images-from-path ["image1.png" "image2.png"] "output.pdf")
+```
+
 ### Split a PDF into mutliple PDDocuments
 ```clojure
  (require '[pdfboxing.split :as pdf])

src/pdfboxing/merge.clj

@@ -1,7 +1,13 @@
 (ns pdfboxing.merge
   (:require [pdfboxing.common :as common])
-  (:import [java.io File FileInputStream]
-           org.apache.pdfbox.multipdf.PDFMergerUtility))
+  (:import (java.io File
+                    FileInputStream)
+           (org.apache.pdfbox.multipdf PDFMergerUtility)
+           (org.apache.pdfbox.pdmodel PDDocument
+                                      PDPage
+                                      PDPageContentStream)
+           (org.apache.pdfbox.pdmodel.common PDRectangle)
+           (org.apache.pdfbox.pdmodel.graphics.image PDImageXObject)))
 
 (defn throw-exception
   [message]
@@ -31,7 +37,40 @@
   [& {:keys [output input]}]
   {:pre [(arg-check output input)]}
   (let [merger (PDFMergerUtility.)]
-      (doseq [f input]
-        (.addSource merger (FileInputStream. (File. f))))
-      (.setDestinationFileName merger output)
-      (.mergeDocuments merger)))
+    (doseq [f input]
+      (.addSource merger (FileInputStream. (File. f))))
+    (.setDestinationFileName merger output)
+    (.mergeDocuments merger)))
+
+(defn- add-image-to-page
+  "Adds image as a page to the document object"
+  [doc ^org.apache.pdfbox.pdmodel.graphics.image.PDImageXObject image]
+  (let [page-size PDRectangle/A4
+        original-width (.getWidth image)
+        original-height (.getHeight image)
+        page-width (.getWidth page-size)
+        page-height (.getHeight page-size)
+        ratio (min (/ page-width original-width) (/ page-height original-height))
+        scaled-width (* original-width ratio)
+        scaled-height (* original-height ratio)
+        x (/ (- page-width scaled-width) 2)
+        y (/ (- page-height scaled-height) 2)
+        page (PDPage. page-size)]
+    (.addPage doc page)
+    (with-open [stream (PDPageContentStream. doc page)]
+      (.drawImage stream image x y scaled-width scaled-height))))
+
+(defn merge-images-from-byte-array
+  "Merges images provided as a vector of byte arrays into one PDF"
+  [images output-doc]
+  (with-open [doc (PDDocument.)]
+    (run! #(add-image-to-page doc (PDImageXObject/createFromByteArray doc % nil)) images)
+    (.save doc output-doc)))
+
+(defn merge-images-from-path
+  "Merges images provided as a vector of string paths"
+  [images output-doc]
+  (with-open [doc (PDDocument.)]
+    (run! #(add-image-to-page doc (PDImageXObject/createFromFile % doc))
+          images)
+    (.save doc output-doc)))

test/pdfboxing/merge_test.clj

@@ -2,18 +2,18 @@
   (:require [clojure.java.io :as io]
             [clojure.test :refer [deftest is]]
             [pdfboxing.common :as common]
-            [pdfboxing.merge :refer [arg-check merge-pdfs]]))
+            [pdfboxing.info :refer [page-number]]
+            [pdfboxing.merge :refer [arg-check merge-pdfs merge-images-from-path]]))
 
 (deftest input-output-argument-check
   (is (thrown? IllegalArgumentException (arg-check)))
   (is (thrown? IllegalArgumentException (arg-check "input")))
   (is (thrown? IllegalArgumentException (arg-check "input" "output")))
   (is (true? (arg-check "output" ["test/pdfs/clojure-1.pdf" "test/pdfs/clojure-2.pdf"]))))
 
-
 (deftest pdf-merge-exit-status
-        (is (nil? (merge-pdfs :output "test/pdfs/foo.pdf"
-                              :input ["test/pdfs/clojure-1.pdf" "test/pdfs/clojure-2.pdf"]))))
+  (is (nil? (merge-pdfs :output "test/pdfs/foo.pdf"
+                        :input ["test/pdfs/clojure-1.pdf" "test/pdfs/clojure-2.pdf"]))))
 
 (deftest pdf-file-merge
   (let [file "test/pdfs/foo.pdf"
@@ -23,10 +23,17 @@
     (is (true? merged-pdf-file))
     (is (true? (common/is-pdf? file)))))
 
+(deftest pdf-image-merge
+  (let [file "test/pdfs/image_merge.pdf"
+        images ["test/images/image1.jpg" "test/images/image2.jpg"]]
+    (merge-images-from-path images file)
+    (is (= (page-number file) 2))))
+
 ;; clean up
 (defn clean-up [file]
   (if (.exists (io/as-file file))
     (io/delete-file file)))
 
 (deftest cleaner
-  (clean-up "test/pdfs/foo.pdf"))
+  (clean-up "test/pdfs/foo.pdf")
+  (clean-up "test/pdfs/image_merge.pdf"))